# Copyright 2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit autotools

DESCRIPTION="htop with vim-style keybindings"
HOMEPAGE="https://github.com/KoffeinFlummi/htop-vim"
SRC_URI="https://github.com/KoffeinFlummi/htop-vim/archive/refs/heads/master.tar.gz -> ${P}.tar.gz"

LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="caps debug hwloc openvz sensors unicode vserver"

DEPEND="
	sys-libs/ncurses:0=[unicode(+)?]
	caps? ( sys-libs/libcap )
	hwloc? ( sys-apps/hwloc:= )
	sensors? ( sys-apps/lm-sensors:= )
"
RDEPEND="${DEPEND}"
BDEPEND="
	virtual/pkgconfig
"

S="${WORKDIR}/${PN}-master"

src_prepare() {
	default
	eautoreconf
}

src_configure() {
	local myeconfargs=(
		$(use_enable caps capabilities)
		$(use_enable debug)
		$(use_enable hwloc)
		$(use_enable openvz)
		$(use_enable sensors)
		$(use_enable unicode)
		$(use_enable vserver)
	)
	econf "${myeconfargs[@]}"
}

src_install() {
	default
	mv "${ED}"/usr/bin/htop "${ED}"/usr/bin/htop-vim || die
	mv "${ED}"/usr/share/man/man1/htop.1 "${ED}"/usr/share/man/man1/htop-vim.1 || die
}