Initial commit

2 files changed, 69 insertions, 0 deletions

diff --git a/x11-terms/st/Manifest b/x11-terms/st/Manifest
new file mode 100644
index 0000000..77df139
--- /dev/null
+++ b/x11-terms/st/Manifest
@@ -0,0 +1 @@
+EBUILD st-9999.ebuild 1368 BLAKE2B f4cd1cc777d8d874fdd35a12d1f870d69eff73b00cccc6b1bc6570eadb7d4b90279f508b77bf23212b455ff87b88916d30330de613bb270f968d9311937e9543 SHA512 63212b7869edefab731764a18a729ce7f006436c5560ca654ac8052cdf4119d3c311d19741a8f7326b93fa6ea913a8ca67f53558dff50d061cb2b11a3433ed46
diff --git a/x11-terms/st/st-9999.ebuild b/x11-terms/st/st-9999.ebuild
new file mode 100644
index 0000000..09e38a4
--- /dev/null
+++ b/x11-terms/st/st-9999.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit desktop git-r3 savedconfig toolchain-funcs
+
+DESCRIPTION="Luke Smith fork of the simple terminal from suckless.org"
+HOMEPAGE="https://git.afu.re/st/"
+EGIT_REPO_URI="https://git.afu.re/${PN}"
+
+LICENSE="MIT-with-advertising"
+SLOT="0"
+KEYWORDS=""
+IUSE="savedconfig"
+
+RDEPEND="
+	>=sys-libs/ncurses-6.0:0=
+	media-libs/fontconfig
+	x11-libs/libX11
+	x11-libs/libXft
+"
+DEPEND="
+	${RDEPEND}
+	x11-base/xorg-proto
+"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e "/^X11LIB/{s:/usr/X11R6/lib:/usr/$(get_libdir)/X11:}" \
+		-e '/^STLDFLAGS/s|= .*|= $(LDFLAGS) $(LIBS)|g' \
+		-e '/^X11INC/{s:/usr/X11R6/include:/usr/include/X11:}' \
+		config.mk || die
+	sed -i \
+		-e '/tic/d' \
+		Makefile || die
+
+	restore_config config.h
+}
+
+src_configure() {
+	sed -i \
+		-e "s|pkg-config|$(tc-getPKG_CONFIG)|g" \
+		config.mk || die
+
+	tc-export CC
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX="${EPREFIX}"/usr install
+
+	make_desktop_entry ${PN} simpleterm utilities-terminal 'System;TerminalEmulator;' ''
+
+	save_config config.h
+}
+
+pkg_postinst() {
+	if ! [[ "${REPLACING_VERSIONS}" ]]; then
+		elog "Please ensure a usable font is installed, like"
+		elog "    media-fonts/corefonts"
+		elog "    media-fonts/dejavu"
+		elog "    media-fonts/urw-fonts"
+	fi
+}
+